Rechercher
 
 

Résultats par :
 


Rechercher Recherche avancée

Connexion

Récupérer mon mot de passe

Chatbox externe


Derniers sujets
» [JEU] Mon voisin du dessous
Mar 10 Oct 2017 - 19:42 par Wistaro

» Lancement du TI-Concours 2017 !
Sam 20 Mai 2017 - 0:27 par Paulo1026

» Chaînes Youtube des membres
Ven 19 Mai 2017 - 22:41 par Wistaro

» cacul du taux d'intêret
Ven 24 Mar 2017 - 21:50 par m@thieu41

» [Projet] Un mario by tout82
Dim 29 Jan 2017 - 14:09 par Wistaro

» Cherche documentation assembleur TI82stat
Mer 25 Jan 2017 - 12:29 par Ti64CLi++

» Probleme Ti-82 Stats fr
Jeu 12 Jan 2017 - 13:56 par Ti64CLi++

» ROM 82 stats.fr
Jeu 15 Déc 2016 - 10:24 par Ti64CLi++

» flappy bird
Jeu 15 Déc 2016 - 10:23 par Ti64CLi++

Partenaires
TI-Planet Espace-TI : Forum

Faire un don à Tout-82...
Où va cet argent ?
Membres donateurs:- Persalteas (10€)
- Wistaro (5€)
- jo2geek (22€)

Les posteurs les plus actifs du mois


Flappy Bird TI-Basic

Voir le sujet précédent Voir le sujet suivant Aller en bas

Flappy Bird TI-Basic

Message par rayane314 le Dim 23 Mar 2014 - 0:15

Salut,

Voila j'ai fait ce flappy bird il y a longtemps et je me suis dit que j'allais le poster Smile

J'ai joint un .zip avec soit les 4 fichiers BIRD,FLAPBIRD,GDB9 et PIC1 distincts soit le tout rassemblé dans un fichier de groupe .tig selon ce que vous preferez.

Pour lancer le programme lancez FLAPBIRD et non BIRD qui lui est un ensemble de fonctions graphiques.

Les commandes :
Enter pour sauter,
Clear pour quitter uniquement dans l'écran titre, et le reste est assez intuitif pour ne pas être explicité Smile

J'ai fait de mon mieux pour optimiser la partie in-game pour un maximum de rapidité et un minimum de place Smile
par contre pour l'autre partie (BIRD) j'ai pas cherché a optimiser c'est totalement imbuvable Razz

Pour ceux qui veulent voir le code :
FLAPBIRD:

Code:
:RecallGDB 9
:Lbl A
:ClrDraw
:RecallPic 1
:{1,40,17
:prgmBIRD
:{4,3,2,25,20,1
:prgmBIRD
:{5,91,2,‾25,20,1
:prgmBIRD
:getKey
:24
:While Ans≠105
:   If Ans=45:Goto C
:   If Ans=24
:   Then
:      {3,2,1,27,22,1
:      prgmBIRD
:      {3,92,1,‾27,22,0
:      prgmBIRD
:      1→Θ
:      0
:   End
:   If Ans=26
:   Then
:      {3,2,1,27,22,0
:      prgmBIRD
:      {3,92,1,‾27,22,1
:      prgmBIRD
:      2→Θ
:      0
:   End
:   getKey
:End
:
:If Θ=2
:Then
:   {6
:   prgmBIRD
:   Pause
:   Goto A
:End
:Lbl B
:ClrDraw
:{2,0,30,2
:prgmBIRD
:{2,0,30,82
:prgmBIRD
:{1,0,42
:prgmBIRD
:{1,79,42
:prgmBIRD
:Line(12,6,82,6
:Horizontal 62
:5→dim(ᴸF
:randInt(17,45→E
:Ans+10→G
:24→A
:0→P
:
:
:For(Θ,16,16,‾4
:   If Θ=16
:   Then
:      Line(20,61,20,7,0
:      52→Θ
:      E→D
:      Ans+10→F
:      randInt(17,45→E
:      Ans+10→G
:   End
:   A→C
:   B+4(B<5→B
:   getKey
:   If Ans=41
:   Then
:      Output(1,1,"√(8547932)"
:      Pause
:   End
:   If Ans=13:Pause
:   If Ans=105
:      ‾7→B
:   A+B→A
:   If Ans<2:2→A
:   If Ans>54
:   Then
:      ‾40→Θ
:      54→A
:   End
:   
:   Θ+4
:   Line(Ans,61,Ans,7,0
:   Pt-Off(28,62-C,2
:   Pt-On(28,62-A,2
:   Ans-4
:   Line(Ans,7,Ans,D
:   Line(Ans,61,Ans,F
:   If Θ<40
:   Then
:      Θ+36
:      Line(Ans,7,Ans,E
:      Line(Ans,61,Ans,G
:      Ans+4
:      Line(Ans,61,Ans,7,0
:   End
:   If Θ=28
:   Then
:      If A≤62-F+1 or A≥62-D-1
:         0→Θ
:      P+1→P
:      Text(3,82,P
:      "ECRIRE APRECIATION
:   End
:End
:
:For(Θ,12,52
:   Line(14,Θ,80,Θ
:End
:For(Θ,15,79
:   Line(Θ,13,Θ,51,0
:End
:Text(12,30,"GAME OVER
:Text(18,23,"YOUR SCORE : ",P
:
:If P>ᴸF(5
:Then
:   ᴸF→L1
:   For(Θ,1,5
:      If P>ᴸF(Θ
:      Then
:         For(Z,Θ,4
:            L1(Z→ᴸF(Z+1
:         End
:         P→ᴸF(Θ
:         6→Θ
:      End
:   End
:   If P>L1(1
:      Text(24,25,"NEW HIGH SCORE
:End
:Text(30,23,"BEST SCORE : ",ᴸF(1
:Text(36,25,"PLAY AGAIN
:Text(42,25,"    1:YES    2:NO
:getKey
:1→Θ
:0
:While Ans≠105
:   getKey
:   If Ans=24
:   Then
:      Text(42,25,"˖
:      Text(42,48,"  
:      1→Θ
:   End
:   If Ans=26
:   Then
:      Text(42,47,"˖
:      Text(42,25,"  
:      2→Θ
:   End
:   If Ans=92
:   Then
:      1→Θ
:      105
:   End
:   If Ans=93
:   Then
:      2→Θ
:      105
:   End
:End
:If Θ=1:Goto B
:For(Θ,0,62
:   Line(0,Θ,94,Θ
:End
:For(Θ,1,61
:   Line(1,Θ,93,Θ,0
:End
:Goto A
:Lbl C
:ClrDraw
:RecallPic 1
:Pause
:ClrDraw
:ClrHome
:Output(1,1,"COPYRIGHT RAYANE 2014"
:Pause
:ClrHome
:"RAYANE 2014
:Output(1,1,"


Attention je vous préviens, celui la est pas beau a voir
BIRD:

Code:
:Ans→L1
:If 1=Ans(1
:Then
:   Line(6+Ans(2),Ans(3),11+Ans(2),Ans(3
:   Line(Ans(2)+4,Ans(3)-1,Ans(2)+12,Ans(3)-1
:   Line(Ans(2)+6,Ans(3)-1,Ans(2)+11,Ans(3)-1,0
:   Pt-On(Ans(2)+9,Ans(3)-1
:   Line(Ans(2)+3,Ans(3)-2,Ans(2)+13,Ans(3)-2
:   Line(Ans(2)+4,Ans(3)-2,Ans(2)+12,Ans(3)-2,0
:   Pt-On(Ans(2)+8,Ans(3)-2
:   Line(Ans(2)+2,Ans(3)-3,Ans(2)+14,Ans(3)-3
:   Line(Ans(2)+3,Ans(3)-3,Ans(2)+13,Ans(3)-3,0
:   Pt-On(Ans(2)+8,Ans(3)-3
:   Pt-On(Ans(2)+12,Ans(3)-3
:   Line(Ans(2)+1,Ans(3)-4,Ans(2)+14,Ans(3)-4
:   Line(Ans(2)+2,Ans(3)-4,Ans(2)+13,Ans(3)-4,0
:   Pt-On(Ans(2)+8,Ans(3)-4
:   Pt-On(Ans(2)+12,Ans(3)-4
:   Line(Ans(2)+1,Ans(3)-5,Ans(2)+14,Ans(3)-5
:   Line(Ans(2)+2,Ans(3)-5,Ans(2)+13,Ans(3)-5,0
:   Pt-On(Ans(2)+9,Ans(3)-5
:   Line(Ans(2)+1,Ans(3)-6,Ans(2)+15,Ans(3)-6
:   Line(Ans(2)+6,Ans(3)-6,Ans(2)+9,Ans(3)-6,0
:   Line(Ans(2),Ans(3)-7,Ans(2)+16,Ans(3)-7
:   Line(Ans(2)+1,Ans(3)-7,Ans(2)+15,Ans(3)-7,0
:   Pt-On(Ans(2)+6,Ans(3)-7
:   Pt-On(Ans(2)+9,Ans(3)-7
:   Line(Ans(2),Ans(3)-8,Ans(2)+15,Ans(3)-8
:   Line(Ans(2)+1,Ans(3)-8,Ans(2)+10,Ans(3)-8,0
:   Pt-On(Ans(2)+5,Ans(3)-8
:   Pt-On(Ans(2)+8,Ans(3)-8
:   Line(Ans(2),Ans(3)-9,Ans(2)+15,Ans(3)-9
:   Line(Ans(2)+1,Ans(3)-9,Ans(2)+14,Ans(3)-9,0
:   Pt-On(Ans(2)+4,Ans(3)-9
:   Pt-On(Ans(2)+9,Ans(3)-9
:   Line(Ans(2)+1,Ans(3)-10,Ans(2)+4,Ans(3)-10
:   Line(Ans(2)+10,Ans(3)-10,Ans(2)+14,Ans(3)-10
:   Line(Ans(2)+5,Ans(3)-10,Ans(2)+9,Ans(3)-10,0
:   Line(Ans(2)+5,Ans(3)-11,Ans(2)+9,Ans(3)-11
:Else
:   If 2=Ans(1
:   Then
:      For(Θ,Ans(2),Ans(3)-5,4
:         Line(Ans(4),Ans(2),Ans(4),Θ
:         Line(Ans(4)+10,Ans(2),Ans(4)+10,Θ
:      End
:      Line(Ans(4),Ans(3)-5,Ans(4)+10,Ans(3)-5
:      For(Θ,Ans(3)-5,Ans(3),4
:         Line(Ans(4)-1,Ans(3)-5,Ans(4)-1,Θ
:         Line(Ans(4)+11,Ans(3)-5,Ans(4)+11,Θ
:      End
:      Line(Ans(4)-1,Ans(3),Ans(4)+11,Ans(3)
:   Else
:      If 3=Ans(1
:      Then
:         Line(Ans(2),Ans(3),Ans(2)+Ans(4),Ans(3),Ans(6
:         Line(Ans(2)+Ans(4),Ans(3),Ans(2)+Ans(4),Ans(3)+Ans(5),Ans(6
:         Line(Ans(2)+Ans(4),Ans(3)+Ans(5),Ans(2),Ans(5)+Ans(3),Ans(6
:         Line(Ans(2),Ans(5)+Ans(3),Ans(2),Ans(3),Ans(6
:      Else
:         If 4=Ans(1
:         Then
:            {3,3,2,25,20,1
:            prgmBIRD
:            For(Θ,‾5,0,1
:               Line(3+25/2+Θ+2.5,2+20/2-Θ,3+25/2+Θ+2.5,2+20/2+Θ
:            End
:         Else
:            If 5=Ans(1
:            Then
:               {3,91,2,‾25,20,1
:               prgmBIRD
:               For(Θ,5,0,‾1
:                  Line(91+‾25/2-2.5-Θ,2+20/2-2.5,91+‾25/2-2.5-Θ,2+20/2-5
:                  Line(91+‾25/2+2.5-Θ,2+20/2+2.5,91+‾25/2+2.5-Θ,2+20/2-5
:                  Line(91+‾25/2+7.5-Θ,2+20/2,91+‾25/2+7.5-Θ,2+20/2-5
:               End
:            Else
:               If 6=Ans(1
:               Then
:                  For(Θ,5,57
:                     Line(10,Θ,84,Θ
:                  End
:                  For(Θ,6,56
:                     Line(11,Θ,83,Θ,0
:                  End
:                  Text(7,29,"HIGH SCORES"
:                  For(Θ,1,5
:                     Text(12+Θ6,20,Θ," : ",ᴸF(Θ
:                  End
:                  
:               End
:               
:               
:            End
:         End
:      End
:   End
:End
:L1



PS:Si vous avez un bug du genre vous êtes tout en bas en début de partie essayez d'appuyer sur enter avant que la partie commence :)sinon si c'est un autre bug prévenez moi !



EDIT: Je rajoute quand même quelques screens au cas ou.




Fichiers joints
FLAPBIRD.zip Flappy Bird.zip(4 Ko) Téléchargé 144 fois

rayane314
Nouveau Venu
Nouveau Venu

Messages : 4
Points Concours : 2
Productivité : 2
Date d'inscription : 22/03/2014

Voir le profil de l'utilisateur

Revenir en haut Aller en bas

Re: Flappy Bird TI-Basic

Message par rayane314 le Lun 24 Mar 2014 - 21:01

C'est clairement un flop..

rayane314
Nouveau Venu
Nouveau Venu

Messages : 4
Points Concours : 2
Productivité : 2
Date d'inscription : 22/03/2014

Voir le profil de l'utilisateur

Revenir en haut Aller en bas

Re: Flappy Bird TI-Basic

Message par Linkakro le Lun 24 Mar 2014 - 22:23

Les flops sont courants. Et bien que je commente voire même améliore une majorité de programme j'arrive à saturation.

Je teste le fichier et j'en conclus déjà des choses.
Les graphismes statiques sont excellent.
Les graphismes mobiles sont simplistes mais cela permet une excellente fluidité.
La taille des tressauts me parait trop grande devant la taille des interstices. Ou bien les interstices trop petits. Mais cela doit être parce que je suis mauvais.
Je trouve que le premier obstacle qui pop en plein milieux de l'écran ne laisse même pas le temps de se placer.
Tu devrais sérieusement stocker les graphismes statiques du jeu dans une Pic. Tu peux dessiner avec le programme une fois puis utiliser la Pic les fois suivantes, tu n'es pas obligé de la fournir comme l'écran titre. Cela sera bien plus agréable pour ceux dans mon cas qui recommencent très souvent.
Le programme routine BIRD me parait banal excepté l'utilisation d'une liste de paramètres graphiques.

__________________________________________________________________________
Vétéran du TI-Basic Zilog80. Ti82statfr sur Tout82 depuis 2009 et ti84pocketfr depuis noël 2012. Ti83plusfrUSB (été 2014, concours tiplanet suite du geek). Bidouille un peu d'assembleur Z80.
Incappable de gérer le temps et manque de tact, plutôt serviable.
Je prend les commandes de programme. Je suis motivé par les maths et la physique tant que ce n'est pas une simple copie d'antisèche.
Vous pouvez trouver une grande partie de mes données hébergées dans mon mediafire. Le ZIP et la liste sont périmées depuis longtemps.
coucou Invité What a Face
avatar
Linkakro
----------------------
----------------------

Messages : 533
Points Concours : 55
Productivité : 31
Date d'inscription : 30/07/2013
Localisation : origine région centre, puis perpignan
Calculatrice(s) :
  • TI-82 Stats.fr

. : TI-82 Stats.fr

Voir le profil de l'utilisateur

Revenir en haut Aller en bas

Re: Flappy Bird TI-Basic

Message par rayane314 le Lun 24 Mar 2014 - 23:32

Ah tout de même :)je commençais à désespérer de ne pas voir de réponses. Mais j'ai enfin ce plaisir (Oui vous savez.. le plaisir qu'on ressent quand quelqu'un utilise notre programme ;)c'est la une bonne motivation)

Et une réponse aussi constructive en plus ! ça réchauffe le cœur xD
Merci pour les graphismes, c'est vrai que c'était une partie assez longue a programmer.

Pour les graphismes mobiles, c'est malgré moi que j'ai mit un point a la place de l'oiseau et des lignes a la place des tuyaux mais oui c’était surtout une question de fluidité et d'optimisation

Alors là je sais pas quoi faire, ça dépends, est-ce qu'un jeu plus facile  est plus attrayant ou l'inverse moi je sais pas répondre :)et puis c'est pas si difficile (j'ai réussi à faire 36 haha)

Ah ça faut que je corrige tu as raison, je viens de voir ça, des fois c'est techniquement impossible de passer !

Ah oui pas faux, à la base j'ai fait exprès de faire apparaître les tuyaux progressivement (d'où les for dans la partie if 2=ans(1 dans BIRD)  mais c'est vrai que ça freine un peu. techniquement je peut aussi afficher mes tuyaux quasi instantanément, sans utiliser de storepic au risque d'en écraser une existant, à voir, c'est quoi le plus avantageux ?

Et pour le menu quand on perd, il est trop lent aussi non ? je dois l’accélérer ?

Oui c'est surtout cette liste dont je suis fier :)C'est simple mais elle me permet d'afficher mon oiseau ou je veux, d'afficher mon tuyaux ou je veux aussi et avec la taille que je veux etc, et ça ça fait le bonheur d'un programmeur !

Sinon tu vois encore quelque chose a optimiser dans la boucle de jeu ?

En tout cas merci d'avoir prit du temps pour moi !

rayane314
Nouveau Venu
Nouveau Venu

Messages : 4
Points Concours : 2
Productivité : 2
Date d'inscription : 22/03/2014

Voir le profil de l'utilisateur

Revenir en haut Aller en bas

Re: Flappy Bird TI-Basic

Message par Linkakro le Mar 25 Mar 2014 - 0:06

Je ne m'inquiète pas des Pic mais ne pas risquer d'écraser est un argument valable. C'est toi qui voit. Moi je prendrais la place pour gagner en efficacité, quitte à modifier un programme moi-même.

Tu gardes le noircissement si tu veux laisser un effet. Moi je blanchirais directement.

Le Goto A dans le Then/End est une source de ralentissement.
http://tout82.free.fr/forum/sujet.php?sujet=2757

Je ne prendrai pas le temps d'analyser le code en détail bientôt.

__________________________________________________________________________
Vétéran du TI-Basic Zilog80. Ti82statfr sur Tout82 depuis 2009 et ti84pocketfr depuis noël 2012. Ti83plusfrUSB (été 2014, concours tiplanet suite du geek). Bidouille un peu d'assembleur Z80.
Incappable de gérer le temps et manque de tact, plutôt serviable.
Je prend les commandes de programme. Je suis motivé par les maths et la physique tant que ce n'est pas une simple copie d'antisèche.
Vous pouvez trouver une grande partie de mes données hébergées dans mon mediafire. Le ZIP et la liste sont périmées depuis longtemps.
coucou Invité What a Face
avatar
Linkakro
----------------------
----------------------

Messages : 533
Points Concours : 55
Productivité : 31
Date d'inscription : 30/07/2013
Localisation : origine région centre, puis perpignan
Calculatrice(s) :
  • TI-82 Stats.fr

. : TI-82 Stats.fr

Voir le profil de l'utilisateur

Revenir en haut Aller en bas

Re: Flappy Bird TI-Basic

Message par rayane314 le Mar 25 Mar 2014 - 22:50

Alors voilà, j'ai suivi tout tes conseils sauf peut-être celui d'agrandir les interstices ^^mais si vraiment tu veux le faire tu peux changer la valeur 10 dans
ans+10->F
et
ans+10->G
tu met celle que tu veux mais je te prévient après il faut redéfinir en conséquence les limites dans le randInt pour pas avoir des espaces trop collés au sol et plafond

C'est vrai que c'est beaucoup plus agréable de pouvoir rejouer très vite !

Alors voilà le code :

FLAPBIRD:

Code:
1→Z
:RecallGDB 9
:Lbl A
:Repeat Ans
:   ClrDraw
:   RecallPic 1
:   {1,40,17
:   prgmBIRD
:   {4,3,2,25,20,1
:   prgmBIRD
:   {5,91,2,‾25,20,1
:   prgmBIRD
:   getKey
:   24
:   While Ans-105
:      If Ans=45:Goto C
:      If Ans=24
:      Then
:         {3,2,1,27,22,1
:         prgmBIRD
:         {3,92,1,‾27,22,0
:         prgmBIRD
:         1→Θ
:         0
:      End
:      If Ans=26
:      Then
:         {3,2,1,27,22,0
:         prgmBIRD
:         {3,92,1,‾27,22,1
:         prgmBIRD
:         2→Θ
:         0
:      End
:      getKey
:   End
:   1
:   If Θ=2
:   Then
:      {6
:      prgmBIRD
:      Pause
:      0
:   End
:End
:
:Lbl B
:ClrDraw
:
:
:If Z
:Then
:   {2,0,30,2
:   prgmBIRD
:   {2,0,30,82
:   prgmBIRD
:   {1,0,42
:   prgmBIRD
:   {1,79,42
:   prgmBIRD
:   Line(12,6,82,6
:   Horizontal 62
:   StorePic 8
:   0→Z
:Else
:   RecallPic 8
:End
:
:
:5→dim(ᴸF
:randInt(17,45→E
:Ans+10→G
:24→A
:0→P
:
:
:For(Θ,72,16,‾4
:   If Θ=16
:   Then
:      Line(20,61,20,7,0
:      52→Θ
:      E→D
:      Ans+10→F
:      randInt(17,45→E
:      Ans+10→G
:   End
:   A→C
:   B+4(B<5→B
:   getKey
:   If Ans=41
:   Then
:      ClrHome
:      Output(1,1,"√(8547932)"
:      Pause
:   End
:   If Ans=13:Pause
:   If Ans=105
:      ‾7→B
:   A+B→A
:   If Ans<2:2→A
:   If Ans>54
:   Then
:      54→A
:      0→Θ
:   End
:   Θ+4
:   Line(Ans,61,Ans,7,0
:   Pt-Off(28,62-C,2
:   Pt-On(28,62-A,2
:   Θ
:   Line(Ans,7,Ans,D
:   Line(Ans,61,Ans,F
:   If Ans<40
:   Then
:      Θ+36
:      Line(Ans,7,Ans,E
:      Line(Ans,61,Ans,G
:      Ans+4
:      Line(Ans,61,Ans,7,0
:   End
:   If Θ=28
:   Then
:      If A≤62-F+1 or A≥62-D-1
:         ‾10→Θ
:      P+1→P
:      Text(3,82,P
:   End
:End
:{3,16,12,62,40,1
:prgmBIRD
:For(Θ,13,51,1
:   Line(17,Θ,77,Θ,0
:End
:Text(12,30,"GAME OVER
:Text(18,23,"YOUR SCORE : ",P
:
:If P>ᴸF(5
:Then
:   ᴸF→L1
:   For(Θ,1,5
:      If P>ᴸF(Θ
:      Then
:         For(Z,Θ,4
:            L1(Z→ᴸF(Z+1
:         End
:         P→ᴸF(Θ
:         6→Θ
:      End
:   End
:   If P>L1(1
:      Text(24,25,"NEW HIGH SCORE
:End
:Text(30,23,"BEST SCORE : ",ᴸF(1
:Text(36,25,"PLAY AGAIN
:Text(42,25,"    1:YES    2:NO
:getKey
:1→Θ
:0
:While Ans≠105
:   getKey
:   If Ans=24
:   Then
:      Text(42,25,"˖
:      Text(42,48,"  
:      1→Θ
:   End
:   If Ans=26
:   Then
:      Text(42,47,"˖
:      Text(42,25,"  
:      2→Θ
:   End
:   If Ans=92
:   Then
:      1→Θ
:      105
:   End
:   If Ans=93
:   Then
:      2→Θ
:      105
:   End
:End
:If Θ=1:Goto B
:{3,0,0,94,62,1
:prgmBIRD
:For(Θ,1,61
:   Line(1,Θ,93,Θ,0
:End
:Goto A
:Lbl C
:ClrDraw
:RecallPic 1
:Pause
:ClrDraw
:ClrHome
:Output(1,1,"COPYRIGHT RAYANE 2014"
:Pause
:ClrHome
:"RAYANE 2014
:Output(1,1,"


Celui la je crois pas l'avoir modifié mais je le met pour être sur.
BIRD:

Code:
:Ans→L1
:If 1=Ans(1
:Then
:   Line(6+Ans(2),Ans(3),11+Ans(2),Ans(3
:   Line(Ans(2)+4,Ans(3)-1,Ans(2)+12,Ans(3)-1
:   Line(Ans(2)+6,Ans(3)-1,Ans(2)+11,Ans(3)-1,0
:   Pt-On(Ans(2)+9,Ans(3)-1
:   Line(Ans(2)+3,Ans(3)-2,Ans(2)+13,Ans(3)-2
:   Line(Ans(2)+4,Ans(3)-2,Ans(2)+12,Ans(3)-2,0
:   Pt-On(Ans(2)+8,Ans(3)-2
:   Line(Ans(2)+2,Ans(3)-3,Ans(2)+14,Ans(3)-3
:   Line(Ans(2)+3,Ans(3)-3,Ans(2)+13,Ans(3)-3,0
:   Pt-On(Ans(2)+8,Ans(3)-3
:   Pt-On(Ans(2)+12,Ans(3)-3
:   Line(Ans(2)+1,Ans(3)-4,Ans(2)+14,Ans(3)-4
:   Line(Ans(2)+2,Ans(3)-4,Ans(2)+13,Ans(3)-4,0
:   Pt-On(Ans(2)+8,Ans(3)-4
:   Pt-On(Ans(2)+12,Ans(3)-4
:   Line(Ans(2)+1,Ans(3)-5,Ans(2)+14,Ans(3)-5
:   Line(Ans(2)+2,Ans(3)-5,Ans(2)+13,Ans(3)-5,0
:   Pt-On(Ans(2)+9,Ans(3)-5
:   Line(Ans(2)+1,Ans(3)-6,Ans(2)+15,Ans(3)-6
:   Line(Ans(2)+6,Ans(3)-6,Ans(2)+9,Ans(3)-6,0
:   Line(Ans(2),Ans(3)-7,Ans(2)+16,Ans(3)-7
:   Line(Ans(2)+1,Ans(3)-7,Ans(2)+15,Ans(3)-7,0
:   Pt-On(Ans(2)+6,Ans(3)-7
:   Pt-On(Ans(2)+9,Ans(3)-7
:   Line(Ans(2),Ans(3)-8,Ans(2)+15,Ans(3)-8
:   Line(Ans(2)+1,Ans(3)-8,Ans(2)+10,Ans(3)-8,0
:   Pt-On(Ans(2)+5,Ans(3)-8
:   Pt-On(Ans(2)+8,Ans(3)-8
:   Line(Ans(2),Ans(3)-9,Ans(2)+15,Ans(3)-9
:   Line(Ans(2)+1,Ans(3)-9,Ans(2)+14,Ans(3)-9,0
:   Pt-On(Ans(2)+4,Ans(3)-9
:   Pt-On(Ans(2)+9,Ans(3)-9
:   Line(Ans(2)+1,Ans(3)-10,Ans(2)+4,Ans(3)-10
:   Line(Ans(2)+10,Ans(3)-10,Ans(2)+14,Ans(3)-10
:   Line(Ans(2)+5,Ans(3)-10,Ans(2)+9,Ans(3)-10,0
:   Line(Ans(2)+5,Ans(3)-11,Ans(2)+9,Ans(3)-11
:Else
:   If 2=Ans(1
:   Then
:      For(Θ,Ans(2),Ans(3)-5,4
:         Line(Ans(4),Ans(2),Ans(4),Θ
:         Line(Ans(4)+10,Ans(2),Ans(4)+10,Θ
:      End
:      Line(Ans(4),Ans(3)-5,Ans(4)+10,Ans(3)-5
:      For(Θ,Ans(3)-5,Ans(3),4
:         Line(Ans(4)-1,Ans(3)-5,Ans(4)-1,Θ
:         Line(Ans(4)+11,Ans(3)-5,Ans(4)+11,Θ
:      End
:      Line(Ans(4)-1,Ans(3),Ans(4)+11,Ans(3)
:   Else
:      If 3=Ans(1
:      Then
:         Line(Ans(2),Ans(3),Ans(2)+Ans(4),Ans(3),Ans(6
:         Line(Ans(2)+Ans(4),Ans(3),Ans(2)+Ans(4),Ans(3)+Ans(5),Ans(6
:         Line(Ans(2)+Ans(4),Ans(3)+Ans(5),Ans(2),Ans(5)+Ans(3),Ans(6
:         Line(Ans(2),Ans(5)+Ans(3),Ans(2),Ans(3),Ans(6
:      Else
:         If 4=Ans(1
:         Then
:            {3,3,2,25,20,1
:            prgmBIRD
:            For(Θ,‾5,0,1
:               Line(3+25/2+Θ+2.5,2+20/2-Θ,3+25/2+Θ+2.5,2+20/2+Θ
:            End
:         Else
:            If 5=Ans(1
:            Then
:               {3,91,2,‾25,20,1
:               prgmBIRD
:               For(Θ,5,0,‾1
:                  Line(91+‾25/2-2.5-Θ,2+20/2-2.5,91+‾25/2-2.5-Θ,2+20/2-5
:                  Line(91+‾25/2+2.5-Θ,2+20/2+2.5,91+‾25/2+2.5-Θ,2+20/2-5
:                  Line(91+‾25/2+7.5-Θ,2+20/2,91+‾25/2+7.5-Θ,2+20/2-5
:               End
:            Else
:               If 6=Ans(1
:               Then
:                  For(Θ,5,57
:                     Line(10,Θ,84,Θ
:                  End
:                  For(Θ,6,56
:                     Line(11,Θ,83,Θ,0
:                  End
:                  Text(7,29,"HIGH SCORES"
:                  For(Θ,1,5
:                     Text(12+Θ6,20,Θ," : ",ᴸF(Θ
:                  End
:                  
:               End
:               
:               
:            End
:         End
:      End
:   End
:End
:L1

Par contre ta dernière phrase est assez paradoxale je dois dire :)Le mélange entre la négation et le bientôt est sujet a controverse, du coup je ne sais pas quoi comprendre
Fichiers joints
FLAPBIRD.zip (3 Ko) Téléchargé 120 fois

rayane314
Nouveau Venu
Nouveau Venu

Messages : 4
Points Concours : 2
Productivité : 2
Date d'inscription : 22/03/2014

Voir le profil de l'utilisateur

Revenir en haut Aller en bas

Re: Flappy Bird TI-Basic

Message par Linkakro le Mar 25 Mar 2014 - 23:12

Pour dire que je suis occupé en temps et saturé en motivation. Ce n'est pas bientôt donc c'est dans une durée longue et indéterminée.

__________________________________________________________________________
Vétéran du TI-Basic Zilog80. Ti82statfr sur Tout82 depuis 2009 et ti84pocketfr depuis noël 2012. Ti83plusfrUSB (été 2014, concours tiplanet suite du geek). Bidouille un peu d'assembleur Z80.
Incappable de gérer le temps et manque de tact, plutôt serviable.
Je prend les commandes de programme. Je suis motivé par les maths et la physique tant que ce n'est pas une simple copie d'antisèche.
Vous pouvez trouver une grande partie de mes données hébergées dans mon mediafire. Le ZIP et la liste sont périmées depuis longtemps.
coucou Invité What a Face
avatar
Linkakro
----------------------
----------------------

Messages : 533
Points Concours : 55
Productivité : 31
Date d'inscription : 30/07/2013
Localisation : origine région centre, puis perpignan
Calculatrice(s) :
  • TI-82 Stats.fr

. : TI-82 Stats.fr

Voir le profil de l'utilisateur

Revenir en haut Aller en bas

Re: Flappy Bird TI-Basic

Message par Contenu sponsorisé


Contenu sponsorisé


Revenir en haut Aller en bas

Voir le sujet précédent Voir le sujet suivant Revenir en haut


 
Permission de ce forum:
Vous ne pouvez pas répondre aux sujets dans ce forum