Bien alors bonne chance !

Merci

Code et screenshoot dès que possible :-)

Voici la version 2.0 !
Screen:

Code:

Code:


:3→dim(L6
:DelVar DDelVar L39→dim(L3
:9→dim(L1:9→dim(L2
:ClrDraw
:AxesOff:ClrDraw
:0→Xmin:1→∆X
:0→Ymax:‾62→Ymin
:51→M:36→N:60→W
:1→T:Lbl 1
:Text(5,28,"‾ TI JUMP! ‾
:Text(38,62,"-
:Text(52,39,"-
:Text(27,43,"-
:For(A,24,71,5
:   Pt-On(A,‾16
:End:Text(57,1,"Wistaro
:Text(57,81,"v2.0
:Repeat getKey
:   For(A,1,W
:      Text(46,38,"π
:   End
:   Text(46,38,"    "
:   For(A,1,W
:      Text(32,61,"π
:   End
:   Text(32,61,"    "
:   For(A,1,W
:      Text(21,41,"π
:   End
:   Text(21,41,"    "
:End:Lbl J
:51→M:36→N
:Menu("*-TI JumP-*","Jouer",9,"Scores",S,"Quitter",Q
:Lbl S:ClrDraw
:Text(1,25,"Meilleurs  scores
:Text(20,1,"1er:  ",L6(1
:Text(35,20,"2e:  ",L6(2
:Text(50,39,"3e:  ",L6(3
:Pause :Goto J
:Lbl 9:ClrDraw
:DelVar CDelVar SDelVar ΘDelVar C1→G
:Lbl 2
:If not(Q:8→D
:If D=2:Then:Text(1,1,int(S
:   Text(M,N,"^
:   DelVar C1→G:End
:If D≠2:Text(M,N,"    "
:DelVar EIf Θ=1:Then
:   S+5→S
:   M+8(D≠2→M
:   For(A,1,9
:      Text(L2(A),L1(A),"  "
:   End
:   For(A,9,2,‾1
:      L1(A-1→L1(A
:      L3(A-1→L3(A
:   End
:   randInt(14,74→L1(1
:   L1(1)+(int(L1(1)/2)=L1(1)/2)→L1(1
:   Q-(D=2→Q
:   If D=2:Goto 2
:   Text(M+7,N+1,"  "
:   If S≥100:1.2→T
:   If S≥200:1.4→T
:   randInt(1,3→D
:   randInt(1,8→U
:   If D=2:1→L3(U
:   If D=1:2→L3(U
:   If L3(U:ClrDraw
:   For(A,1,8,T
:      round(A,0→A
:      If not(L3(A:Text(L2(A),L1(A),"-
:      If L3(A)=2:Text(L2(A),L1(A),"+
:      If L3(A)=1:Text(L2(A),L1(A),"+
:   End
:   Goto Θ:End
:For(A,1,57,8
:   E+1→E
:   randInt(14,74→B
:   B+(int(B/2)=(B/2→B
:   B→L1(E:A→L2(E:Text(L2(E),B,"-
:End:Lbl Θ
:Lbl 3
:ClrHome
:Vertical 13
:Vertical 81
:StorePic 1
:Repeat K=45 or M=55
:   RecallPic 1
:   Text(1,1,int(S
:   If M<52:Then
:      If Pxl-Test(M+10,N+2) and not(Pxl-Test(M+10,N+1:Then
:         Pause "FUSEE!
:         20→Q:2→D:Goto 2:End
:      If Pxl-Test(M+10,N+3) and Pxl-Test(M+10,N+1:Goto 5
:   End
:   If M=9:Then
:      1→Θ:Goto 2:End
:   getKey→K
:   Text(M,N,"π
:   If K=34:Then:Text(30,36,"Pause
:      Pause :DelVar KClrDraw:RecallPic 1:End
:   If K=24 and N≠14:Then
:      Text(M,N+4,"    ":N-2→N:End
:   If K=26 and N≠74:Then:Text(M,N-4,"      ":N+2→N:End
:   If K=26 and N=74:Then:Text(M,N,"    ":14→N:End
:   If K=24 and N=14:Then:Text(M,N,"      ":74→N:End
:   If Pxl-Test(M+7,N+2:DelVar C1→G
:   If G:Then:M-2→M:C+1→C:S+1→S:End
:   If C=10:DelVar G
:   If not(G:Then:C-1→C:M+2→M:S-.4→S:End
:   If M<53:Text(M+4,N,"      "
:   Text(1,1,"      ":End
:Lbl 5
:1→M:ClrDraw
:DelVar DText(7,30,"GAME OVER!
:Text(20,1,"Score: ",S
:If S>L6(3:S→L6(3
:If S>L6(2:Then:L6(2→L6(3:S→L6(2:End
:If S>L6(1:Then
:   L6(1→L6(2:L6(2→L6(3
:   S→L6(1:End
:If S≤L6(3
:Then
:   Text(30,1,"A battre: ",L6(3:
:Else:Text(30,1,"Meileur score!
:End
:Pause :Goto J:End
:End:End
:Lbl Q:ClrDraw
:DelVar CDelVar GDelVar SDelVar L1DelVar L2
 

Alors?

Wistaro a écrit:Je travaille sur un V2 avec, entre autres:
-Une rapidité augmentée
- Ajout de plaques mouvantes
- Ajout de monstres
- Ajout d'un système de shop
- Ajout de bonus/malus

Bien mais à quoi ça correspond sur ton screenshot ?

Tout n'apparaît pas sur le screennshoot:
#Monstres = M
#Ressorts= +

Ok et bien + 1

Super!

Tu ne voudrais pas utiliser le scrolling de Wlib ?

Grave ! Ce serait mieux...

blg_flg a écrit:Tu ne voudrais pas utiliser le scrolling de Wlib ?

Pourquoi pas.... :-) Je n'ai jamais utiliser Wlib, faut que je regarde sa.

NB: Si vous êtes sur TI-82, je vous déconseille d'utiliser de nombreuses fois le boost. Après utilisation, le programme ralentit fortement (pourquoi??)

Voici pourquoi le boost cause un ralenti. Tu as placé un goto dans des alternatives.

Code:

:      If Pxl-Test(M+10,N+2) and not(Pxl-Test(M+10,N+1:Then
:         Pause "FUSEE!
:         20→Q:2→D:Goto 2:End

Il y a d'autres exemples dans ton programme.

Ma source. http://tout82.free.fr/forum/sujet.php?sujet=2757

Le fait que tu signales la Ti82 :
- ne dis pas juste 82. Confusion Ti82stats.
- je n'avais pas testé le bug sur les ti flash, c'est à voir

Bien vu, pour le goto, je n'y avais pas pensé. Je vais essayer de contourner ce soucis.

Probablement que le bogue ne se ressent pas parce que la calto va plus vite.

J'ai testé ce code:

Code:

For(A,0,1
If not(A
Goto 1
End
Disp 0
Return
Lbl 1
Disp 1
End

Sur ti 82stats et sur 83+/84+SE, ça me donne la même chose (ça affiche 0 puis 1), donc le Goto interfère bien de la même façon avec les boucles.

Quand à savoir si ça ralentis bien la calto...
J'ai fait ce code pour qu'on se rende mieux compte:

Code:

0->A

Lbl 1
While 1 //Boucle qui sert à simuler le bogue

Disp A
A+1->A

If not(getKey
Goto 1 //On va rentre à nouveau dans la boucle

J'ai testé sur 82stats.fr/83+/84+SE, les 3 ti ralentissent (même si la 84+ va toujours plus vite et la 83+ est plus lente (même par rapport à la ti82stats.fr))

Dans l'ordre, de gauche à droite:
TI82stats.fr/84+SE/83+

Ce bug n'est donc pas corrigible?

Non car c'est le fonctionnement même du TI-Basic.
A toi de ne pas créer de situation usant des goto à mauvais escient.
Quelques manières d'éviter les défauts sont présentes dans mon article que j'ai cité. Mais la solution la plus stable est l'algorithmie.

Ce que je n'avais pas testé est le potentiel ralentissement des tiflash que m@thieu41 a comparé aux autres. Le conflit entre l'algorithmie et les goto était déjà connu sur toutes les tiZ80.

Ca a l'air super comme jeu mais je ne comprends pas pourquoi à chaque scrolling les pixels disparaissent et réapparaissent...
Et une autre petite question : le jeu tourne-t-il à la même vitesse que sur le gif ?

En ti basic il est impossible de faire un scroll efficace de l'écran graphique, en "déplaçant" les pixels. Il faut donc mieux (dans un cas similaire au cas présent) effacer l'écran et tout ré-afficher.

(A mon avis) le gif a été pris sur une 84+ (ou au moins une 83+ puisqu'il y a des petits caractères dans le texte).
Donc la vitesse risque d'être moins importante sur 82stats/83.
Mais quand tu poses une question de ce type, veille à préciser ton modèle.

j'imagine que c'est une 84+, mais si c'est une 83+, le jeu sera plus rapide que le screenshot sur 82stats (d'apres ma comparaison de fsnake sur une ti83+ et une 82stats) et ce n'est pas une fatalité, car il y a matrefeytontias!!! hé oui!!! notre dieu en matière de ti avec sa w-lib!!!!!!
Et n'oubliez pas qu'une ti non-flash va en général plus vite qu'une ti flash, c'est pourquoi la ti83+ a une cadence de 8Mhz contre 6Mhz pour la ti82(stats) puisque sinon, ca serait trop lent deja que ca l'est beaucoup quand la ROM est pleine.

La ti 84+ est une ti flash beaucoup plus rapide que la ti 82stats, donc ne tire pas des conclusions trop hâtives.

WLib permet de faire plein de choses, mais je ne vois pas ici pourquoi ça rendrait le jeu plus rapide.
L'affichage du perso ce fait avec du texte, donc c'est rapide, contrairement à l'utilisation d'un sprite qui pourrait être plus longue (il faudrait pour l'afficher/effacer lancer le programme qui lance WLib (ce qui est assez long selon matref), alors qu'un texte se fait en une seule commande, et ne nécessite pas d'appeler un autre prgm). Je pense que l'utilisation de sprites est utile lorsqu'on veut un perso plus réaliste, et qu'il y a beaucoup de sprites à afficher d'un coup (je ne sais pas si matref a prévu de faire en sorte qu'on puisse afficher plusieurs sprites d'un coup, mais ça pourrait permettre de bannir certains problèmes de vitesse).
Par contre l'utilisation de WLib permettrait d'avoir un scrolling.

Il y a aussi quelques optimisations possibles dans le code et qui permettraient de gagner un peu de vitesse:
Privilégier la multiplication à la division:

Code:

B+(int(B/2)=(B/2→B

devient:

Code:

B+(int(B.5)=B.5→B

ou encore:

Code:

B+not(fPart(.5B→B

Ne pas fermer les guillemets/parenthèses etc:

Code:

L1(1)+(int(L1(1)/2)=L1(1)/2)→L1(1

devient:

Code:

L1(1)+(int(L1(1)/2)=L1(1)/2→L1(1

ou encore

Code:

L1(1)+(int(.5L1(1))=.5L1(1→L1(1

ou

Code:

L1(1)+not(fPart(.5L1(1→L1(1

Réduire le nombre de conditions si possible:

Code:

:  If K=26 and N≠74:Then:Text(M,N-4,"      ":N+2→N:End
:  If K=26 and N=74:Then:Text(M,N,"    ":14→N:End

devient:

Code:

If K=26
Then
Text(M,N-4(N!=74),"      "
N+2-62(N=74→N
End

Houlà ... N'importe quoi rpgcreator. Les TI-82 stats, 83+ et 84+ ont exactement le même processeur. La seule chose qui change est le niveau de bridage : seule la 84+ peut tourner à 15 MHz en plus de 6 MHz, les deux autres sont bloquées à 6 MHz. Les TI non-flash tournent plus vite parce que l'OS n'a pas à se soucier des diverses manipulations de page flash qui n'ont lieu d'être que sur TI-Flash.

Oui, j'ai pris le screenshoot sur un TI84+. Mais je compte faire une version "allégée" du programme, et compatible TI-82/TI-82Stats

Merci M@thieu pour ces optimisations ;-)

Antox98: par défaut, je n'efface pas tout l'écran, mais une boucle efface seulement les plaques. Lorsque un bonus est affiché sur l'écran, j'efface tout l'écran