Bonjour à tous,

Aujourd'hui je vous présente mon nouveau jeu, 2048!
Il s'agit d'une adaptation du jeu sur smartphone, réalisée en TIbasic z80 et compatible TI82/83/84/+
Voici un screenshoot:
Ainsi que le code:

Code:

:DelVar Θ
:ClrDraw:AxesOff
:0→Xmin:0→Ymin
:1→∆X:1→∆Y
:DelVar [A]{4,4→dim([A]
:Lbl 9
:ClrHome
:Menu("  Design?","Default",D,"Manual",M,"Random",R
:Lbl R
:randInt(1,3→M
:randInt(1,7→L
:Goto 2
:Lbl D:2→L:2→M:Goto 2
:Lbl M
:Disp "Type?1=·/2=□/3=˖
:Input "",M
:If not(max(M={1,2,3:Goto 9
:Disp "Size?
:Input "",L
:abs(L→L
:Lbl 2
:ClrDraw
:DelVar L<sub>1</sub>DelVar L<sub>2</sub>
:randInt(1,4→V
:randInt(1,4→W
:For(A,12,62,L
:Pt-On(22,A,M
:Pt-On(48,A,M
:Pt-On(72,A,M
:End
:For(A,0,94,L
:Pt-On(A,24,M
:Pt-On(A,38,M
:Pt-On(A,52,M
:End
:StorePic 1
:DelVar B
:{1,26,51,76→L<sub>1</sub>
:{0,13,28,42→L<sub>2</sub>
:Repeat K=72
:getKey→K
:If K=94:Goto Q
:Text(1,1,"Menu>
:Text(13,27,"Play
:Text(28,52,"Optn
:Text(43,78,"Exit
:Text(55,10,"*****2048*****
:If K=83:Goto 9
:End
:ClrDraw:RecallPic 1
:DelVar Z2→A:2→B
:Lbl 1
:DelVar [A]{4,4→dim([A]
:ClrDraw:RecallPic 1
:2→[A](randInt(1,4),randInt(1,4)
:Lbl 5
:For(A,1,4
:For(B,1,4
:Text(L<sub>2</sub>(A),L<sub>1</sub>(B),"        "
:If [A](A,B:Text(L<sub>2</sub>(A),L<sub>1</sub>(B),[A](A,B
:End:End
:Repeat K=45
:getKey→K
:Text(55,40,Θ
:If K=45:Stop
:If max(K={24,25,26,34:Then
:If K=26 or K=34:Then
:1→I:3→J:1→L
:End
:If K=24 or K=25:Then
:4→I:2→J:‾1→L
:End
:If K=26 or K=24:Then
:For(W,1,4
:For(V,I,J,L
:If [A](W,V)=[A](W,V+L):Then
:[A](W,V)+[A](W,V+L)→[A](W,V+L:0→[A](W,V
:Θ+2[A](W,V+L→Θ
:End
:If not([A](W,V+L:Then
:[A](W,V)→[A](W,V+L
:0→[A](W,V
:End
:End:End:End
:If K=34 or K=25:Then
:For(W,1,4
:For(V,I,J,L
:If [A](V,W)=[A](V+L,W:Then
:[A](V,W)+[A](V+L,W)→[A](V+L,W
:0→[A](V,W
:Θ+2[A](V+L,W→Θ
:End
:If not([A](V+L,W:Then
:[A](V,W)→[A](V+L,W
:0→[A](V,W
:End
:End:End:End
:Repeat not([A](E,F
:randInt(1,4→E
:randInt(1,4→F
:End
:2→[A](E,F
:Goto 5
:End:End:End

Enfin, voici le lien de téléchargement: http://tiplanet.org/forum/archives_voir.php?id=43458

Vous pouvez créer votre propre design!


N'hésitez pas à me proposer vos suggestions, vos optimisations et vos questions!

@++

Bravo mais un la calculatrice met du temps à exécuter le programme...

Je sais, il faut que j'optimise l'algorithme pour augmenter la vitesse

Ce programme n'est pas compatible tel quel avec la TI82 non-stat puisque tu utilises l'optimisation des tests multiples avec max(). Remplaces avec plusireurs tests et je crois bien que ce sera compatible.

La présentation est bonne. Mais personnellement je n'aime pas les bordures en curseurs de points carrés.

Je relève le défi de mon côté car j'aime l'algorithmie.

Linkakro a écrit:Ce programme n'est pas compatible tel quel avec la TI82 non-stat puisque tu utilises l'optimisation des tests multiples avec max(). Remplaces avec plusireurs tests et je crois bien que ce sera compatible.

Je l'ignorais. Mais peu d'utilisateur utilisent des TI82 non stats, alors j'ai voulu privilégier l'optimisation.

Linkakro a écrit:
La présentation est bonne. Mais personnellement je n'aime pas les bordures en curseurs de points carrés.

Justement, le design modulable est fait pour sa. Tu peux mettre ce que tu veux.

Linkakro a écrit:
Je relève le défi de mon côté car j'aime l'algorithmie.

Bon courage!

Il y a ça, sinon.

Le code ! Le code ! Le code ! ! ! (Pitié que ce soit pas de l'asm, sinon ce n'est pas approprié pour ce topic...)

Je recommande de poster un sujet à part pour cet autre programme, car tout se mélange sinon. Ou encore indique un sujet existant ailleurs.
http://espace-ti.forumactif.com/t1074-2048-with-animations
Et pito, je confirme que ce n'est pas du TI-Basic. Des mouvements aussi fluides sont typiques de l'assembleur.

C'est la version de Nikitouzz, en Axe.
Donc, impossible sur TI82...

Le code Axe ne peut être compilé directement pour TI83 et TI82stats mais le résultat compilé peut être adapté comme le JetPack de Matrefeytontias.

J'ai réalisé ce jeu sur ma calto, je le poste dès que je prendrai le temps de le recopier.

Je vais aussi regarder ton algo, en tous cas ça a l'air rapide (à moins que ce ne soit du à une différence TI 83/84+ ? )

Bien joué  

m@thieu41 a écrit:
Je vais aussi regarder ton algo, en tous cas ça a l'air rapide (à moins que ce ne soit du à une différence TI 83/84+ ? )

Bien joué  

Rapide, mais je suis sûr que tu peux faire mieux
En plus, le mien comporte quelques bugs de déplacement que je doit corriger

Ouf ! Je croyais que je m'étais trompé dans le recopiage, en effet de temps en temps, lorsque tu appuies sur flèche droite ou gauche ou peu importe, ça ne se déplace pas toujours, puis les nombres ne s'additionnent pas toujours. Mais bravo quand même !   

Merci.

Je suis déjà passé à un autre jeu xD

Désolé j'avais zappé ce sujet...

Voici mon code (je poste seulement l'algo de déplacement des données dans la matrice):

Code:

Repeat max(Rép
codeTouche={24,25,26,34,45,21->L1
End

If Rép(5
Goto M //Menu
If Rép(6
Goto P //Mode Furtif

//C : si à 1 on transpose la matrice (pour gérer les colonnes avec le même algo que les lignes)
//E : Sens de déplacement (-1/1)
max(L1{0,0,1,1,0,0->B
max(L1{0,1,0,1,0,0->C
1-2B->E

If C
[A]T->[A] //T de transpose

DelVarN3-B->M // M correspond au numéro de la case la plus éloignée qui peut être déplacée par rapport au sens de déplacement
For(W,1,4
For(A,3B+1,M,E //permet de parcourir toutes les cases de la ligne dans le bon sens

[A](W,A->Q //La case courante
A->G //Le numéro de case destination (dans la ligne)
Repeat G=M+E ou Rép+H //Jusqu’à ce qu’on aille à la dernière case où qu’on puisse déplacer ou que le déplacement soit bloqué (case non nulle qu’on ne peut pas déplacer)
G+E->G //Case suivante
[A](W,G->H //On récupère le contenu
Rép=Q et Rép ou Répnon(Q //Si la case suivante contient le même nombre non nul ou si la case suivante contient un nombre et pas la case courante
End

If Rép //Si on déplace
Then
H+Q->[A](W,A //On ajoute la case déplacée à la case cible
0->[A](W,G //On reset la case déplacée
A-Enon(Q->A //Au prochain passage il faudra reprendre la même case cible si on a fait un déplacement simple sans ajout
N+1->N //Ca c’est pour interdire les coups blancs: si N vaut 0 on ne rajoute pas de nouveau nombre aléatoirement
S+2Q->S //Gestion du score
Else //Si on a pas déplacé
If non(Q
G->A //Si la case courante était vide, et qu’on n’a pas fait de déplacement, c’est qu’il n’y en a plus à faire sur cette ligne, donc on change de ligne (G sera égal à M+E)
End

End
End

If C //On redresse la matrice au besoin
[A]T->[A]

Je procède donc ainsi :
Je relève la case courante
Je cherche quelle case pourrait aller dessus (un nombre quelconque si la case était vide ou le même nombre si la case était remplie)
Je déplace ou j’ajuste la case courant.

Est-ce le code complet pour faire fonctionner le jeu ? Ou bien faut-il l'adapter au code de Wistaro (Si oui, comment ?) ?

M@thieu41 a clairement écrit que ce n'est qu'un programme de déplacement. Donc seulement la chute des nombres vers les bords.
Moi aussi j'oublie ce thème. Je préfère mes boucles For et variables intermédiaires mais je bloque sur la détection des grilles bloquées. J'ai programmé les transformations de matrice (symétrie et transposée) mais c'est trop lent.

Qu'entends tu par juste "un programme de déplacement" ? C'est le jeu complet ?

Non, c'est juste l'algo qui permet de gérer les déplacements des cases en mémoire.
Je posterai le jeu complet plus tard, mais il faut que je le recopie, je n'ai pas le câble.

Merci de vos travaux les gars !

De rien :p

Bonjour
et si on se faisait un petit concours pour le 2048 ?
pour ti82stat en version basic ?

Qui veut mais pas ici. Nouveau sujet.
Le mien inédit ne détecte pas la défaite.

Bonsoir
Alors je laisse le soin, à qui veut, de faire un nouveau billet ; si ça intéresse quelqu'un...

Personnellement, non j'attends avec impatience la version complète de M@t... Mais prends ton temps, j'imagine que tu as beaucoup d'autres choses à faire...

Bon bah alors tant pis.

Personnellement, non j'attends avec impatience la version complète de M@t... Mais prends ton temps, j'imagine que tu as beaucoup d'autres choses à faire...

Tu fais bien de me le rappeler, j'avais zappé   
J'ai récupéré un câble la semaine dernière, donc le prgm est sur mon ordi, faut que je modifie 2-3 détails et je poste, mais d'abord faut que je finisse mon prgm pour le concours ti planet, je posterai ça sûrement mardi.

COOL !