Le MINSTEP (jeu)

Bonjour chers amis,
j'ai l'honneur de vous présenter un autre petit jeu de ma création le MINSTEP. C'est un petit jeu où on est un petit + qui se fait courser par trois * il faut survivre le plus longtemps possible. Il fait 1036 octets et est optimisable (hésitez pas   ). J'espère que ça vous plaira. Il faut utiliser les touches directionnel et 'enter' pour le mettre en pause.

Et maintenant en exclusivité la version 2 avec un niveau facile en plus (une mine en moins), et un bug réparé!



Le lien : http://www.4shared.com/file/ID-MJnYD/MINSTEP.html

Code:

:Lbl M
:ClrHome 
:4→A:8→B:1→C:1→D:1→E:8→G:16→H:16→F:DelVar UDelVar VDelVar WDelVar S1→J:1→N
:3→dim(ᴸMINS  // ᴸ c'est le petit L dans [liste], MINS  s'écrit avec alpha plus les lettres
:Lbl D
:Menu("MINSTEP","JOUER",0,"NIVEAU",1,"RECORDS",3,"QUITTER",2
:Lbl 3
:Disp "RECORD:","","FACILE:","NORMAL:","DIFFICILE:"
:Output(3,8,ᴸMINS(1
:Output(4,8,ᴸMINS(2
:Output(5,11,ᴸMINS(3
:Pause
:Goto D
:Lbl 1
:Menu("NIVEAU","FACILE",A,"NORMAL",B,"DIFFICILE",C
:Lbl A
:DelVar N
:Goto D
:Lbl B
:1→N
:Goto D
:Lbl C
:2→N
:Goto D
:Lbl 0
:While J
:ClrHome
:Output(A,B,"+
:If not(U
:Output(C,D,"*
:If not(V) and N
:Output(E,F,"*
:If not(W
:Output(G,H,"*
:getKey→K
:B-(K=24 and B>1)+(K=26 and B<16→B
:A-(K=25 and A>1)+(K=34 and A<8→A
:If K=105
:Then
:Output(4,6,"PAUSE
:Pause
:End
:If N≤2
:randInt(1,3)→T          // entAléat dans [maths]
:If N=2
:randInt(1,2)→T
:If T=1:Then
:C+(A>C and not(U))-(A<C and not(U→C
:E+(A>E and not(V) and N)-(A<E and N and not(V→E
:G+(A>G and not(W))-(A<G and not(W→G
:End
:If T=2:Then
:D+(B>D and not(U))-(B<D and not(U→D
:F-(B<F and not(V) and N)+(B>F and N and not(V→F
:H+(B>H and not(W)-(B<H and not(W→H
:End
:S+1→S
:If not(U
:(E=C and F=D and N or C=G and D=H→U
:If not(V
:(E=C and F=D or E=G and F=H→V
:If not(W
:(G=E and H=F and N or G=C and H=D→W
:If U or V or W
:Then
:U+(U≠0)→U
:V+(V≠0)→V
:W+(W≠0)→W
:End
:If U
:Output(C,D,"X
:If V and N
:Output(E,F,"X
:If W
:Output(G,H,"X
:If U≥9
:Then
:DelVar U
:1→C:1→D
:End
:If V≥9
:Then
:DelVar V
:1→E:16→F
:End
:If W≥9
:Then
:DelVar W
:8→G:16→H
:End
:If A=C and B=D or A=E and B=F and N or A=G and B=H
:0→J
:End
:ClrHome
:Pause "BOOOOOOOOOOOOOM!
:Output(4,4,"GAME OVER
:If S>ᴸMINS(N+1
:S→ᴸMINS(N+1
:Pause
:ClrHome
:Disp "   GAME OVER    // 3 espaces avant
:Disp "SCORE:",S,"BEST:",ᴸMINS(N+1
:Pause
:Goto M
:Lbl 2

Bonjour,

Impossible de télécharger ton prgm, je tombe sur cette pasge: http://s1.packupload.com/R9RML0NKS2L

Sinon sur ton code:

Code:

If U=0

->

Code:

If non(U

Code:

:  If K=25 and A>1
:      A-1→A
:  If K=34 and A<8
:      A+1→A

->

Code:

A-(K=25 and A>1)+(K=34 and A<8→A

Pareil pour B. (avec des valeurs différentes pour K= et A>/<

Code:

:If N<1 or N>2
:  1→N

Pourquoi cette sécurité? J'ai peut être loupé quelque chose mais je crois que tu initialises N à 1 ou à 2 en fonction de la difficulté choisi, et que tu ne changes plus après non? Alors N<1 ou N>2 renverra toujours faux... En fait non je vois que tu peux avoir N=? si tu choisis de jouer sans rentrer de niveau...
Il suffit de rajouter 1->N dans les initialisations du début:

Code:

:4→A:8→B:1→C:1→D:1→E:8→G:16→H:16→F:0→U:0→V:0→W:0→S:1→J:1->N

Ensuite pour initialiser à 0, utilises DelVar :

Code:

:DelVar WDelVar UDelVar VDelVar S4→A:8→B:1→C:1→D:1→E:8→G:16→H:16→F:1→J:1->N

Code:

:  If N=1
:      randInt(1,3)→T
:  If N=2
:      randInt(1,2)→T
:  If T=1:Then
:      If A>C and U=0
:        C+1→C
:      If A<C and U=0
:        C-1→C
:      If A>E and V=0
:        E+1→E
:      If A>G and W=0
:        G+1→G
:      If A<G and W=0
:        G-1→G
:  End
:  If T=2:Then
:      If B>D and U=0
:        D+1→D
:      If B<D and U=0
:        D-1→D
:      If B<F and V=0
:        F-1→F
:      If B>H and W=0
:        H+1→H
:      If B<H and W=0
:        H-1→H
:  End

->

Code:


:      randInt(1,4-N→T //Si N = 1 , 4 - N = 3, si N = 2, 4-N = 2
:  If T=1:Then
:        C+non(U)((A>C)-(A<C→C //On peut peut être trouver mieux
:        E+(A>E and non(V→E
:        G+non(W)((A>G)-(A<G→G
:  End
:  If T=2:Then
:        D+non(U)((A>D)-(A<D→D
:        F+(A>F and non(V→F
:        H+non(W)((A>H)-(A<H→H
:  End

Code:

:Disp "  GAME OVER
:Disp "SCORE:",S
:Disp "BEST:",L6(3
:Pause

->

Code:

:Disp "  GAME OVER","SCORE:",S,"BEST:"
:Pause L6(3

Et un petit dernier:

Code:

:Menu("NIVEAU","NORMAL",A,"DIFFICILE",B
:Lbl A
:1→N
:Goto M
:Lbl B
:2→N

->

Code:

:1
:Menu("NIVEAU","NORMAL",A,"DIFFICILE",B
:Lbl B
:Ans+1
:Lbl A
:Ans->N

Plusieurs optimisations possibles sur ton code sont décrites dans cet article: https://tout82.forumactif.org/t50-candide-ou-l-optimisation

Voilà

Bin le lien c'est ça : http://www.packupload.com/R9RML0NKS2L Si il te dit que c'est périmé il te donne un nouveau lien... Sinon j'avais juste la flemme de vraiment l'optimiser, je le ferais plus tard (le pire c'est que je connais toutes ces astuces) en fait je parlais aussi du prog en lui-même il pourrait-être mieux mais bon pour l'instant je ne compte pas l'améliorer.

m@t a écrit:Pourquoi cette sécurité? J'ai peut être loupé quelque chose mais je crois que tu initialises N à 1 ou à 2 en fonction de la difficulté choisi, et que tu ne changes plus après non? Alors N<1 ou N>2 renverra toujours faux... En fait non je vois que tu peux avoir N=? si tu choisis de jouer sans rentrer de niveau...
Il suffit de rajouter 1->N dans les initialisations du début:

En fait c'est juste pour que si le mec a mis difficile il aura encore difficile en remettant le prog je fais ça sur tout mes progs mais t'as surement raison. Une habitude.

Quand je clique sur le lien il me met patientez 15, 14... 0 puis Téléchargez. Je clique dessus et je tombe ici : http://s1.packupload.com/R9RML0NKS2L

packupload est a chier essaie avec 4shared ca marche c gratuit

Merci du conseil!

Le lien est valide maintenant (+ image)!

Merci pour ton optimisation m@t, juste : ça bousille l'IA d'une mine...   . En fait non quand la E F arrive sur la case 5, 16 (je crois) elle s'immobilise. T'as une idée?

Je me permets aussi de te suggérer MediaFire.

J'ai testé c'est sympa comme jeux  
Tu pourrais peut être faire un niveau "facile" avec seulement 2 adversaires, le niveau normal est compliqué avec 3.

ash a écrit:ça bousille l'IA d'une mine... Sad . En fait non quand la E F arrive sur la case 5, 16 (je crois) elle s'immobilise. T'as une idée?

Que veux tu dire par là?

Merci du compliment.

Un niveau facile pourquoi pas, y a un bug aussi qu'il faut que je résolve.

Pour le coup de la mine c'est la mine n°2 de coordonnées (E,F) qui se bloque quand elle arrive sur la "case" de coordonnées (6,16). Ce qui assez incompréhensible pour moi.

Sinon je pourrais encore pas mal l'améliorer, il est pas si génial (je préfère le taptaupe il est plus abouti) mais bon pour l'instant j'ai la flemme. En attendant je vais tenter de rajouter le niveau facile et de détruire le bug (le truc aussi en facile c'est que ton highscore n'as pas la même valeur en facile, moyen, et difficile faudrait faire trois emplacement dans une liste mais c'est chiant on s'y retrouve plus après).

Pour stocker les meilleurs scores j'ai fait un article qui détaille le sujet ici: https://tout82.forumactif.org/t60-sauvegarder-des-donnees
Je ne l'ai pas encore fini (il faut que je modifie 2-3 trucs suite au post de Linka), mais tu verras qu'il n'est pas très compliqué de stocker 3 meilleurs scores...

Nan mais ça va je sais hein, c'est juste que ça prend de la place dans la mémoire de faire des listes de 1600 nombres de long, quant au listes personnalisées y en a un nombre limité non? Donc pour un jeu comme ça un seul meilleur score ça suffit...

Bah non justement, les listes personnalisées il y en a quasiment une infinité (dans la limite des combinaisons de noms possibles en fait, et bien sur de la mémoire disponible).
Et tu n'as pas besoin d'une liste de 1600 nombres de longs: tu fais une liste personnalisée qui s'appelle LMINST, de dimension 3, dans le premier terme tu stocke le meilleur score du mode facile, dans le deuxième celui normal, puis dans le 3e le difficile. Après tu peux regarder dans mon tuto il y a des techniques de compressions si tu veux économiser quelques octets.
Tandis que si tu utilises L6, tu as des risques de perdre tes données, si un autre programme décide de l'utiliser, tandis qu'avec une liste personnalisée tu as moins de chances que ça arrive.

Ah ouais!? Mais moi je croyais que tu pouvais faire genre que cinq liste personnalisée!

UP : J'ai rajouté une capture d'écran animée.

ca, c'était sur la ti 82 grise (ou il yavait seulement 6 listes dispos, de l1 a l6).
maintenat, la ti82stats (qui est, pour la enieme fois, une ti83) possede 999 listes differentes, dont les listes l1 a l6. donc non, ce n'est pas une infinité, car il y a 26 caracteres possibles:
36+ 36^2 +36^3 +36^4 +36^5 =62193780 listes différentes, car on n'est pas obligé de taper 5 chiffres et lettres differentes; par rapport a 999 listes differentes, y a quand meme une difference notable   

Pourquoi tu parles de 999 listes?
Et il y a une restriction à prendre en compte: le premier caractère doit être une lettre, les suivants peuvent être un chiffre, et le théta est autorisé.
Donc ça fait 27*37^4 = 50 602 347 listes différentes.
Mais bon sachant qu'on a que 27Ko de RAM, la question est réglée, on en a une infinité  

Il confond 999 termes avec le nombre de listes.

ti 82 : 6 listes de 99 termes chacune
ti82stats : 6 listes de base de 999 termes chacune et 27*37^4 listes personnalisées de 999 termes chacune

Quant au jeu MINSTEP, je n'ai pas le temps de regarder et pas le courage de me plonger dans les optimisations comme au bon vieux temps et comme fait m@thieu41 en permanence. Désolé...

excus, je pense que je regarde tout et n'importe quoi, du coup je me suis dit qu'il y a 999 listes differentes. Fin du HS!!!!!
tu peux mettre un affichage avec les meilleurs scores comme ca ca donne envie au mec qui lance le prog de faire mieux

Linkakro a écrit:Quant au jeu MINSTEP, je n'ai pas le temps de regarder et pas le courage de me plonger dans les optimisations comme au bon vieux temps et comme fait m@thieu41 en permanence. Désolé...

Bin pourquoi? Rien ne t'y oblige, le faire est un plus, ne pas le faire n'est pas un moins.

rpgcreator a écrit:tu peux mettre un affichage avec les meilleurs scores comme ca ca donne envie au mec qui lance le prog de faire mieux

???  ??? Je le fais déjà à la fin du jeu, tu veux dire faire une option du menu? Perso je trouve ça pas super important, après bon ça peut se faire assez facilement mais bon...

ah, maismets le au debut!!! pour que le mec qui joue ait envie de faire mieux!!!!

Bin si tu veux, mais d'abord j'ai l'intention de l'améliorer (virer le bug de la triple explosion, etc.).

ashtrail a écrit:

Linkakro a écrit:Quant au jeu MINSTEP, je n'ai pas le temps de regarder et pas le courage de me plonger dans les optimisations comme au bon vieux temps et comme fait m@thieu41 en permanence. Désolé...

Bin pourquoi? Rien ne t'y oblige, le faire est un plus, ne pas le faire n'est pas un moins.

bah ne compte pas sur linkakro
matthieu41 est beaucoup plus disponbible sur ce genre de programmes (basic) !!!

Oui mais justement c'est ce que je disais, tu ne m'apprends rien là... De plusce n'est pas "compter" sur Linka on dirait que c'est un crime de ne pas aider qqn à optimiser son jeu.

UP : J'ai enlevé le bug enfin! Et puis j'ai optimisé le programme (désolé m@t mais je ne comprends pas assez bien tes optimisations du coup je fais des erreurs j'ai moins de chance de faire des bugs en optimisant par moi même, cependant j'ai appris grâce à toi). Je poste le nouveaux prog sous peu mais je ne suis toujours pas satisfait il faut que je fasse un niveau facile, peut-être des maps avec des trucs explosifs, une IA un peu moins bancale, un jeu plus beau peut-être. Enfin bref je ne suis pas près de l'avoir fini.

Ash a écrit:désolé m@t mais je ne comprends pas assez bien tes optimisations du coup je fais des erreurs j'ai moins de chance de faire des bugs en optimisant par moi même, cependant j'ai appris grâce à toi

Pas de problème (c'est même une très bonne idée d'essayer de trouver des améliorations par soi même, ça veut dire que le métier rentre ), si tu as des questions sur des remarques que j'ai faites n'hésites pas.

Ça y'est la version 2 est arrivée! J'ai mis un niveau facile, et l'IA des mines buggue moins. Le bug qui survenait quand les 3 mines s'explosaient en même temps et ne ressuscitaient jamais est réparé. Il y a aussi maintenant trois scores différents pour chaque niveaux!
Au niveau optimisation on peut surement faire mieux mais je pense que t'auras moins de boulot que la dernière fois m@t!

Si on est vraiment un maniaque de l'optimisation niveau octets:

Code:

16→H:16→F

devient

Code:

16→H:Rép→F //On gagne un octet!

----------------

Code:

If not(V) and N

devient

Code:

If Nnot(V

---------------

Code:

:If N≤2 //≤ c'est pas super vu que tu feras les 2, < à la place
:randInt(1,3)→T //Parenthèse fermantes?
:If N=2
:randInt(1,2)→T //idem

Un peu de booléens:

Code:

:randInt(1,3-(N=2→T

----------------

Code:

:C+(A>C and not(U))-(A<C and not(U→C
:E+(A>E and not(V) and N)-(A<E and N and not(V→E
:G+(A>G and not(W))-(A<G and not(W→G

tu peux enlever certains and:

Code:

:C+not(U)(A>C)-(A<C and not(U→C
:E+not(V)(A>E and N)-(A<E and N and not(V→E
:G+not(W)(A>G)-(A<G and not(W→G

Quand tu as:
A+(not(X) and A>V
Il suffit de décaler la parenthèse et le and saute:
A+not(X)(A>V

Quand tu veux une condition (et non une affectation qui se sert de booléens:
If N and not(X
tu peux multiplier:
If Nnot(X

Mais pas en affectation j'insiste:
C+(N and not(X
Est différent de
C+Nnot(X
je pense que tu vois pourquoi

+1 pour le jeu, il a l'air très sympa, beau boulot

Merci Wistaro,
Sinon j'incorpore quelques uns de tes conseils m@t, mais pas tous je ne suis pas un maniaque mouhahaha! Enfin libre à toi de le modifier si tu l'as téléchargé.

je pousserais pas autant que m@t, mais les parenthèses, quand meme...
enfin, bref, c'est toujours quand tu essaies d'enlever des parenthèses que tu te retrouves avec un p***** de bug de m*****!!! perso, ca m'a toujours embêté dans mes RPG...

Rhâ les paranthèses c'était un oubli! Dans tous le reste du code je ne les mets pas. Pareil pour le inférieur ou égal à 2.

On te pardonnes .