Le plus léger Papy-Jump.

Salut !
Je viens de réussir à terminer un papy-saute avec des listes. Il tient en seulement 250 octets. Il est aussi plus fluide.
PAPY-JUMP V4

Code:

:EffEcr
:7->X:1->Y:1->H:8->P:0->S
:Entaléat(1,16,7->L1
:7->L1(8
:Repeat Y=8
:For(A,1,8
:Output(A,L1(A),"=
:End
:If S=4 ou H=1 et X=L1(Y+1
:Then:-H->H:0->S
:End
:S-H->S
:CodeTouche->T
:If non(Y+H
:Then:For(A,-7,-1
:L1(-A->L1(-A+1
:End
:entaléat(1,16->L1(1
:EffEcr:Output(8,15,P
:Y+1->Y
:End
:Output(Y,X," "          -------- "1 espace"
:X-(T=24)+(T=26->X
:Y+H->Y
:If X=0:16->X:If X=17:1->X
:Output(Y,X,"O
:End

Pourquoi pas plus léger ? :

Code:

ClrHome
DelVar S7->X:1->Y:1->H:8->P
randInt(1,16,7->L1
7->L1(8
Repeat Y=8
For(A,1,8
Output(A,L1(A),"=
End
If S=4 or H=1 and X=L1(Y+1
Then:DelVar S-H->H
End
S-H->S
getKey->T
If not(Y+H
Then:For(A,-7,-1
L1(-A->L1(1-A
End
randInt(1,16->L1(1
ClrHome:Output(8,15,P
Y+1->Y
End
Output(Y,X,"
X-(T=24)+(T=26->X
Y+H->Y
X-16(X=17)+16not(X->X
Output(Y,X,"O
End

Une amélioration du papy saute...
J'ai remarquer que dans un seul cas, la commande "If" peut faire exécuter deux autres commandes.
Example; Si on écrit ce petit prgm :

Code:

:1-B
:Input A
:If A=3
:EffVar AA->B
:Disp A,B

Et bien si et seulement si A=3, 0->A et A->B.
Je m'en suis servi pour supprimer un "If:Then:End" dans le code d'après.
J'ai aussi optimiser la condition ":If S=4 ou HX=L1(Y+1".
Voilà pour vous
PAPY-JUMP V4,2
221 octets

Code:

:EffEcr
:1->Y:1->H:EffVar S8->P
:Entaléat(1,16,8->L1
:L1(1->X
:Repeat Y=8
:For(A,1,8
:Output(A,L1(9-A),"=
:End
:If S=4 ou HX=L1(8-Y
:EffVar S-H->H           -------- la touche (-)
:S-H->S
:If non(Y+H:Then
:suite(L1(A+1),A,1,7->L1
:entaléat(1,16->L1(8
:EffEcr:P+1->P
:Y+1->Y
:End
:codeTouche
:Output(Y,X,"         
:X-(Rép=24)+(Rép=26->X
:X+16non(X)-16(X=17->X
:Y+H->Y
:Output(Y,X,"O
:End
:P


Merci à toi Mingerton

Tu as encore quelques octets octets à gagner, que j'ai déjà indiqué plus haut

Code:

ClrHome
7->X:1->Y:1->H:DelVar S8->P          // ici
randInt(1,16,7->L1
7->L1(8
Repeat Y=8
For(A,1,8
Output(A,L1(A),"=
End
If S=4 ou HX=L1(Y+1
DelVar S-H->H
S-H->S
getKey->T
If not(Y+H
Then:For(A,-7,-1
L1(-A->L1(-A+1
End
randInt(1,16->L1(1
ClrHome:P+1->P:Output(8,15,P
Y+1->Y
End
Output(Y,X,"                        // et là
X-(T=24)+(T=26->X
Y+H->Y
X-16(X=17)+16not(X->X                  // et là aussi
Output(Y,X,"O
End

Waw excellent les gars

Sur l'autre Tout82, ld (RTX7) a fait encore plus léger. 220 octets c'est propre :

Code:

:EffEcr
:1->Y:1->H:EffVar S8->P
:Entaléat(1,16,8->L1
:Rép(1->X
:Repeat Y=8
:For(A,1,8
:Output(A,L1(9-A),"=
:End
:If S=4 ou HX=L1(8-Y
:EffVar S-H->H
:S-H->S
:If non(Y+H:Then
:suite(L1(A+1),A,1,7->L1
:entaléat(1,16->L1(8
:EffEcr:P+1->P
:Y+1->Y
:End
:codeTouche
:Output(Y,X,"          
:X-(Rép=24)+(Rép=26->X
:X+16non(X)-16(X=17->X
:Y+H->Y
:Output(Y,X,"O
:End