Prgm PlatForming

Bonjour,
je vous présente mon nouveau jeu, platforming.



Comme son nom l'indique, il s'agit d'un jeu de plate-forme, sur TI, en TI-basic.

Le jeu est actuellement en projet, il me faudrais des idées pour le créer.

J'ai fait la création de map, le passage de lvl... Bref allez voir dans le lien ci-dessous

Pour l'instant, il n'est pas très amusants, je compte sur vous pour me donner vos idées

Code:

Code:

:ClrDraw
:DelVar KDelVar IDelVar L:1→M
:0→Xmin:1→ΔX
:0→Ymin:1→ΔY
:GridOff:Full:AxesOff
:Text(57,60,"Loading..."
:Text({-}1,9,10,"Plat Forming"
:Text(20,30,"by Wistaro"
:Pause
:Menu(" PlaTForming","Jouer",J,"Quitter",Q
:Lbl J:ClrDraw
:DelVar GDelVar H
:15→A:10→B
:Text(0,0,"Generating level...
:If I:Goto J2
:Menu("Mode","Plein",M1,"Invisible",M2
:Lbl M1:1→I:Goto J2
:Lbl M2:10→I:Goto J2
:Lbl J2
:For(C,1,20
:randInt(0,94→U
:randInt(0,45→V
:Line(U,V,U,0
:randInt(1,15→W
:Line(U,V,U+W,V
:Line(U+W,V,U+W,0
:For(L,U,U+W,I
:Line(L,V,L,0
:End:End
:For(F,54,62
:Line(0,F,70,F,0
:End
:Text(1,2,"Level:":For(Z,1,M*10
:randInt(0,92→S
:randInt(0,61→T
:Pt-On(S,T
:End
:Horizontal 62
:Vertical 0
:Line(0,54,30,54
:Line(30,54,30,62
:Repeat K=45
:DelVar K
:getKey→K
:If B=93:Then
:M+1→M:Goto J
:End
:Text(1,26,M
:Pxl-On(A,B
:Pxl-On(A+1,B
:Pxl-On(A+1,B+1
:Pxl-On(A,B+1
:If K=26 and pxl-Test(A,B+2)=0 and pxl-Test(A+1,B+2)=0:Then:B+1→B:Pxl-Off(A,B-1:Pxl-Off(A+1,B-1:End
:If K=24 and pxl-Test(A,B-1)=0 and pxl-Test(A+1,B-1)=0:Then:B-1→B:Pxl-Off(A,B+2:Pxl-Off(A+1,B+2:End
:If K=25 and (pxl-Test(A+2,B)=1 or pxl-Test(A+2,B+1)=1):1→G
:If G=1:Then:A-1→A:H+1→H:Pxl-Off(A+2,B:Pxl-Off(A+2,B+1
:End
:If H=15 or pxl-Test(A-1,B)=1 or pxl-Test(A-1,B+1)=1:Then:0→G:0→H:End
:If G=0 and pxl-Test(A+2,B)=0 and pxl-Test(A+2,B+1)=0:A+1→A
:Pxl-Off(A-1,B
:Pxl-Off(A-1,B+1
:End

Lien: http://tiplanet.org/forum/archives_voir.php?id=20186

En tout cas, c'est super beau !

Par contre, tu ne peux pas utiliser de Text(-1 sur 82...

ça me fait penser aux jeux de Worms que je connais qui y ressemblent:
Une équipe de personnages tire sur l'équipe adverse, faisant de plus en plus de trous dans les montagnes

Oui pour le -1 il est optionnel je vais l'enlever
J'aivu le Worms, mais pour la création de la map j'ai pas du tout fait pareil

C'et beau, mais faut trouver un "game-play"
Pour l'instant le but pour passer de niveau est de traverser la map et plus le niveau est élevé, plus le nombre de points sur l'écran augmente.
Ces points servent à bloquer le joueur, mais même avev sa, je trouve le jeu d'une simplicité...démoralisante

En tout cas je suis d'accord c'est super beau! (en plus en seulement quelques lignes de TI Basic!)

Quelques idées (après je sais pas si c'est possible ou non):

- Rendre le saut moins performant parce que ça participe à la facilitée.
- Mettre des plateformes qui tiennent dans les airs (et pourquoi pas mobiles tant qu'on y est)
- Mettre des ennemis ou alors des piques pour qu'on puisse mourir autrement qu'en tombant.

Voila, voila. En tout cas bravo pour le design!

Tu veut dire remplacer les points par des plate-formes, ou garder les point + les plate-formes?
Les piques: +1, je vais essayer d'ajouter sa
Les ennemis: Sa risque d'être compliqué, mais pourquoi pas, je vais essayer.
Il faut pas que sa ralentisse trop le jeu non plus

Pour les plateformes comme tu veux. C'est juste des idées qui me sont venues comme ça. T'as aucune obligations vis-à-vis d'elles. Mais si ça t'aide tant mieux (au fait un lien est prévu?).

OK

Oui, voici le lien: http://tiplanet.org/forum/archives_voir.php?id=20186

Je vais essayer de l'améliorer ce soir, si j'ai un peu de temps

Les points, c'est joli, faut les laisser

Les plateformes pourraient être au dessus des montagnes, si tu fais des montagnes moins hautes

ça créerait un décor à plusieurs étages

Je suis d'accord, c'est super beau, ça a l'air prometteur.
Des plates formes mouvantes, ou qui s'effondrent, ça pourrait être pas mal.
Peut être aussi une gestion du vent qui nous pousserait? (avec un indicateur en haut de l'écran)

Code:

:Pxl-On(A,B
:Pxl-On(A+1,B
:Pxl-On(A+1,B+1
:Pxl-On(A,B+1

Il semble que ceci est le carré que l'on dirige. Tu gagnerais peut-être en fluidité avec un simple Pt-On(A,B,2.

Par ailleurs, les labels type J2 ou M2 ne fonctionnent pas non plus sur 82.

Pour le reste, bravo !

C'est magnifique et tellement simple !  

(persalteas dit 82 pour 82/82stat(fr) et blg_flg dit 82 pour 82 seulement, c'est source de confusion)

Tu pourrais peut-être utiliser Shade/Ombre pour tracer les rectangles et pas forcément depuis le bas. Et pas seulement des rectangles.
Cependant il faut définir des fonctions booléennes dans les arguments pour éviter les lignes en trop...
Shade(y1,y2,x1,x2 // pour faire simple
Shade((X > x1)(X < X2)y1,(X > x1)(X < X2)y2,x1,x2 // pour enlever les lignes de courbe en trop, mais on a toujours des verticales en x1 et x2 et une horizontale à zéro.

Merci à tous!

J'ai amélioré le jeu hier soir, je mettrais les nouveaux codes ce soir.
En attendant,. voici ce que j'ai modifié grâce à vos idées:

> En cours de partie "CLEAR" revient au menu d'accueil.
> Comme disait persal, j'ai diminué légèrement la taille du décor "lié" au sol pour ajouter un décore qui "flotte" en l'air . Le rendu est plutôt pas mal, vous verrez ce soir :p
> Modification des labels M2/M1 et J1/J2.


M@thieu41: Pour les platformes mouvantes, j'ai peur que sa ne ralentisse trop le jeu...
Pour la gestion du vent, je vais y réfléchir. Sa me parait être une bonne idée, mais peut être difficile à mettre en place

Linkakro: Sa serair plus rapide pour le chargement qu'utiliser des boucles ?

waaaaoooh !! c'est vrai que c'est magnifique!!! c'est fluide, rapide, on dirait un jeu asm.
mais la, y a quasiment aucun objectif, ce qui est normal, vu la rapidite. c'est pas mal, on a tous nos facilités a faire tels types de jeux: moi, c'est les RPG, toi les jeux de plateforme. continue comme ca, +1 pour le projet!

Merci rpgcreator, mais je ne compte pas m'arreter la, je vais l'améliorer

Voici le code, après les correctif ci dessus

Code:

:Lbl A
:ClrDraw
:DelVar KDelVar IDelVar L:1→M
:0→Xmin:1→∆X
:0→Ymin:1→∆Y
:GridOff:Full:AxesOff
:Text(57,60,"Loading..."
:Text(9,10,"Plat Forming"
:Text(20,30,"by Wistaro"
:Pause
:Menu(" PlaTForming","Jouer",B,"Quitter",Q
:Lbl B:ClrDraw
:DelVar GDelVar H
:15→A:10→B
:If I:Goto J
:Menu("Mode","Plein",C,"Invisible",D
:Lbl C:1→I:Goto J
:Lbl D:10→I:Goto J
:Lbl J
:Text(0,0,"Genarating level
:For(C,1,20
:randInt(0,94→U
:randInt(0,45→V
:Line(U,V,U,0
:randInt(1,15→W
:Line(U,V,U+W,V
:Line(U+W,V,U+W,0
:For(L,U,U+W,I
:Line(L,V,L,0
:End:End
:For(Z,1,M*5
:randInt(0,92→S
:randInt(0,61→T
:randInt(1,15→U
:randInt(1,10→V
:
:For(Θ,T,T+V,I
:Line(S,Θ,S+U,Θ
:End:End
:
:For(F,54,62
:Line(0,F,70,F,0
:End
:Text(1,2,"Lvl:"
:Horizontal 62
:Vertical 0
:Line(0,54,23,54
:Line(23,54,23,62
:Repeat K=45
:DelVar K
:getKey→K
:If B=93:Then
:M+1→M:Goto B
:End
:Text(1,15,M
:Pxl-On(A,B
:Pxl-On(A+1,B
:Pxl-On(A+1,B+1
:Pxl-On(A,B+1
:If K=26 and Pxl-Test(A,B+2)=0 and Pxl-Test(A+1,B+2)=0:Then:B+1→B:Pxl-Off(A,B-1:Pxl-Off(A+1,B-1:End
:If K=24 and Pxl-Test(A,B-1)=0 and Pxl-Test(A+1,B-1)=0:Then:B-1→B:Pxl-Off(A,B+2:Pxl-Off(A+1,B+2:End
:If K=25 and (Pxl-Test(A+2,B)=1 or Pxl-Test(A+2,B+1)=1):1→G
:If G=1:Then:A-1→A:H+1→H:Pxl-Off(A+2,B:Pxl-Off(A+2,B+1
:End
:If H=13 or Pxl-Test(A-1,B)=1 or Pxl-Test(A-1,B+1)=1:Then:DelVar GDelVar H:End
:If G=0 and Pxl-Test(A+2,B)=0 and Pxl-Test(A+2,B+1)=0:A+1→A
:Pxl-Off(A-1,B
:Pxl-Off(A-1,B+1
:End
:Goto A

EDIT; le pxt(A,B,2) ne fonctionne pas, je travaille sur le systéme des pts(x,y)

Pour passer de pt à pxl facilement, il faut bien choisir la fenêtre et ne pas être piégé par le bug de réinit de Y.

Oublie ma proposition de Shade : elle est absolument trop lente.
Je croyais que ses fonctionnalités seraient pratiques et que le système irait vite, mais non. Elle perd son temp à tracer les courbes paramètres. Je viens de tester pour être sûr.

En fait, je crois que dessiner quatre pixels ou un Pt-On(A,B,2 reviens au même niveau temps d'exécution. J'ai rapidement testé et on ne note aucune différence flagrante.

Moi je vois la différence à l'oeil nu et avec deux émulateurs. Pt est plus rapide car une seule interprétation des arguments est faite au lieu de quatre.
Pt-On(A,B,2 ne dessine pas exactement la même chose que les 4 pxl.

EDIT: j'ai tracé 93 points pour que la différence soit visible

Ah ben je suis bigleux, si tu as bien testé avec 2 en argument facultatif. C'est donc une bonne option, à mon avis, d'autant plus que je trouve cela plus esthétique.

Linkakro a écrit:Pour passer de pt à pxl facilement, il faut bien choisir la fenêtre et ne pas être piégé par le bug de réinit de Y.

La bonne fenetre? C'est à dire? Que en gros le repere soit le même pour les pt() que pour les pxt() (et donc les txt() aussi)
Mais comment?

En cherchant un peu, je suis tombé sur le message de Linkakro:
Pour changer de repère, il faut appliquer la formule:
X2=Xmin2+(X1-Xmin1)*(Xmax2-Xmin2)/(Xmax1-Xmin1)


Mais je ne comprend toujours pas comment l'appliquer...

Ça ne voulait pas simplement dire de prendre une fenêtre avec Xmin et Ymin égaux à zéro et Xmax et Ymax respectivement égaux à 94 et 62 ?

Pour une meilleure correspondance, on peut prendre:

Code:

0->Xmin
94->Xmax
-62->Ymin
0->Ymax

Du coup, c'est juste que les fonctions utilisant le zoom (Ligne pt-on...) utilisent l'opposée de l'ordonnée par rapport aux fonctions qui se positionnent par rapport aux pixels de l'écran (Text, pxl-on et autres)

Humm je vais essayer sa

Au fait un conseil : le jeu n'as pas de but, on joue juste pour jouer, je pense que tu devrais mémoriser le niveau le plus haut auquel on est arrivé pour créer un highscore et ainsi motiver le joueur. Mais bon c'est comme tu veux.

C'est vrai, mais le plus important ça reste de trouver un but au jeu, autre que de monter des lvl (parce que parcourir sans difficulté l'écran de gauche à droite ça va 5min ).

Je vois que les changements de repère posent encore des problèmes.
Je vais énoncer les deux solutions élémentaires puis illustrer ma formule générale.

Voici la source où j'ai posté initialement la formule. http://tout82.free.fr/forum/sujet.php?message=50255#50255

Solution simple négative :

Code:

0->Xmin
94->Xmax
0->Ymax
-62->Ymin
pt-On(A,B
pxl-On(-B,A

Solution simple complémentée :

Code:

0->Xmin
94->Xmax
62->Ymax
0->Ymin
pt-On(A,B
pxl-On(62-B,A

Solution complète et compliquée

Spoiler:

Merci, mais est-ce que le différence de rapidité justifie vraiment de faire tout cela?

Bah ça permet d'avoir un truc plus cohérent, et ce n'est pas très compliqué d'initialiser la fenetre...
Ca permet de gagner en place, en cohérence et en rapidité.

En cohérence?

Avoir des coordonnées cohérentes dans les repères graphique et pixel est un avantage considérable.
Cela facilite le développement et permet d'utiliser facilement n'importe quel repère. On a même le choix pour certaines fonctionnalités.

La formule complète de conversion de repère devient justement inutile quand le graphique est correctement configuré.

En plus tu peux stocker le zoom ou utiliser les affectations d'échelles pour configurer rapidement le graphique plus tard.
http://espace-ti.forumactif.com/t719-optimisation-062094