[prgm] SOKOBATI

par **Wistaro** Mer 10 Sep 2014 - 18:52

Et salut à tous, je vous présente (enfin) mon nouveau jeu, il s'agit de SOKOBATI!

J'ai réalisé ce jeu en Mai 2014, mais je l'avais complètement oublié xD

SOKOBATI est un jeu basé sur le principe du Sokoban.
Le principe est de déplacer des caisses dans des endroits prévus à cet effet et ainsi accéder au niveau suivant lorsque toutes les caisses sont sur une bonne case.

Comment y jouer?

Au menu:

- Choisir son niveau: choisir un chiffre entre 1 et 9.

En mode jeu:

- Se déplacer: touches directionnelles
- Pousser une caisse: se placer devant la face de la caisse voulue et effectuer une pressions sur celle-ci dans la directions voulue.
- Symbole d'une caisse: "0"
- Symbole d'un mur: "8"
- Symbole d'un emplacement: "[]"
- Valider/vérifier: 2NDE

Mode édition de niveau:

Le programme vous permet également de créer vos propres niveaux. Pour cela, allez dans "edit lvl" au menu.
Voici comment faire ensuite:

- Créer une caisse: 2ND
- Créer un emplacement de caisse: ENTER
- Créer un mur: ALPHA
- Effacer un item (mur, caisse...): se positionner dessus et DEL
- Réinitialiser le niveau: CLEAR

Une fois votre niveau terminé, appuyez sur ON puis 1.

Ensuite, allez dans 2ND, puis X-1 (Matrix), puis tapez le chiffre 0. Ensuite, appuyez sur STO->, puis 2ND, puis X-1 (Matrix).

Là, choisissez le niveau dans lequel votre carte sera enregistrée. Par exemple, si vous cliquez sur [F], le niveau sera enregistré comme étant le niveau 6.

Puis appuyez sur ENTER. Votre niveau est sauvegardé! Pour y accéder, relancez SOKOBATI dans les programmes, et choisissez votre niveau Smile

(6 dans mon exemple)

Téléchargement de niveaux supplémentaires:

Vous pouvez télécharger des niveaux supplémentaires ici gratuitement et partager les vôtres ici: http://bit.ly/1wfuhwz

Code source - Jeu principal (SOKOBATI)

:Lbl 0
:DelVar L
:"[A][C][D][E][F][G][H][I]->Str1
:Menu("SOKOBATI","JOUER",3,"EDIT LVL",4,"INFO",8
:Lbl 8
:ClrHome
:Disp "BY WISTARO 
:Disp "(C) - May 2014
:Disp "
:Disp "DOWLOAD LVLS 
:Disp "PACKS ON:
:Disp "
:Disp "WWW.SOKOBATI.TK
:Disp 
:Pause 
:Goto 0
:Lbl 4
:prgmSOKOEDIT
:Goto 0
:Lbl 3
:0->Ymin:1->DeltaX
:0->Ymin:1->DeltaY
:DelVar L
:ClrDraw:ClrHome:AxesOff
:DelVar [A]{9,16->dim([A]
:For(A,1,16
:3->[A](1,A
:3->[A](9,A
:End
:For(B,1,9
:3->[A](B,1
:3->[A](B,16
:End
:2->[A](6,9
:2->[A](4,13
:2->[A](3,5
:1->[A](2,2
:1->[A](2,15
:1->[A](5,12
:Output(3,1,"(1 - 9)
:Input "LVL?: ",R
:String>Equ(sub(Str1,R,1),{Y1}
:{Y1}->[J]:DelVar {Y1}
:Disp "LOADING...
:DelVar L1DelVar L2seq(A,A,1,94,6)->L1
:seq(B,B,1,58,7)->L2
:8->V:5->W
:Lbl 1
:ClrDraw
:For(A,1,9
:For(B,1,16
:If [J](A,B)=3:Text(L2(A),L1(B),"8
:If [J](A,B)=2:Text(L2(A),L1(B),"O
:If [J](A,B)=1
:Text(L2(A),L1(B),"[]
:End:End
:Lbl 6
:If L:Then
:Disp "CHECKING...
:DelVar O
:For(A,1,9
:For(B,1,16
:O+([J](A,B)=1->O
:End:End:End
:If L and not(O:Then
:Pause "FINISH!
:Goto 0
:End
:If L:Then
:Disp "IL RESTE",O,"CAISSES
:Pause 
:DelVar LClrHome
:End
:Repeat K=21
:getKey->K
:Text(L2(W),L1(V),"^
:If K:Text(L2(W),L1(V),"   "
:If W>2:Then
:If K=25 and [J](W-1,V)=2 and [J](W-2,V)<=1:Then
:Text(L2(W-1),L1(V),"    "
:Text(L2(W-2),L1(V),"O
:2->[J](W-2,V
:0->[J](W-1,V
:End:End
:If V>2:Then
:If K=24 and [J](W,V-1)=2 and [J](W,V-2)<=1:Then
:Text(L2(W),L1(V-1),"    "
:Text(L2(W),L1(V-2),"O
:2->[J](W,V-2
:0->[J](W,V-1
:End:End
:If V<15:Then
:If K=26 and [J](W,V+1)=2 and [J](W,V+2)<=1:Then
:Text(L2(W),L1(V+1),"    "
:Text(L2(W),L1(V+2),"O
:2->[J](W,V+2
:0->[J](W,V+1
:End:End
:If W<8:Then
:If K=34 and [J](W+1,V)=2 and [J](W+2,V)<=1:Then
:Text(L2(W+1),L1(V),"    "
:Text(L2(W+2),L1(V),"O
:2->[J](W+2,V
:0->[J](W+1,V
:End:End
:V+(K=26 and not([J](W,V+1)))-(K=24 and not([J](W,V-1->V
:W+(K=34 and not([J](W+1,V)))-(K=25 and not([J](W-1,V->W
:End
:1->L:Goto 6

[b]Code source - Editeur (SOKOEDIT)

:0->Xmin:1->DeltaX
:0->Ymax:~62->Ymin
:Lbl 9:ClrDraw
:8->V:5->W
:DelVar [J]{9,16->dim([J]
:DelVar L1DelVar L2seq(A,A,1,94,6)->L1
:seq(B,B,1,58,7)->L2
:Lbl 5:ClrDraw
:Repeat K=45
:getKey->K
:Pxl-Change(L2(W),L1(V)
:not(Z->Z
:If Zmax(K={24,25,26,34}
:DelVar ZPxl-Change(L2(W),L1(V)
:If K=45:Goto 5
:V+(K=26 and V<16)-(K=24 and V>1->V
:W+(K=34 and W<9)-(K=25 and W>1->W
:If K=105:Then
:Text(L2(W),L1(V),"[]
:1->[J](W,V)
:End
:If K=23:Then:
:Text(L2(W),L1(V),"     "
:0->[J](W,V
:End
:If K=31:Then
:Text(L2(W),L1(V),"8
:3->[J](W,V
:End
:If K=21:Then
:Text(L2(W),L1(V),"O
:2->[J](W,V)
:End
:End
:Return
:Lbl 2
:DelVar {9,16->dim([B]
:DelVar [A]{9,16->dim([A]
:For(A,1,16
:3->[A](1,A
:3->[A](9,A
:3->[B](9,A
:3->[B](1,A
:End
:For(B,1,9
:3->[A](B,1
:3->[A](B,16
:3->[B](B,1
:3->[B](B,16
:End
:2->[A](6,9
:2->[A](4,13
:2->[A](3,5
:1->[A](2,2
:1->[A](2,15
:1->[A](5,12
:

[b]Screenshoot
[prgm] SOKOBATI 1410367460sokoban

Lien direct de téléchargement (les 2 fichiers)
http://tiplanet.org/modules/archives/download.php?id=91262

Vous pouvez télécharger des niveaux supplémentaires ici gratuitement et partager les votres ici: http://bit.ly/1wfuhwz

N'hésitez pas à partagez vos niveaux, impressions, avis, suggestions... Smile

par **Linkakro** Mer 10 Sep 2014 - 19:46

Bien. Tout à fait raisonnable et fonctionnel.

Je cherche comment le Lbl 2 devrait être lu. Ni menu ni Goto. confused

Cette présentation est riche en couleur ! Quel éditeur as-tu utilisé ?
Je préfère placer les codes colorés dans des quote ou spoiler plutôt que de le laisser trainer quitte à ne pas utiliser code.
Le forum a manifestement un soucis avec les balises bbcode de gras... je cherche un lien avec les formatages html de couleur des codes.

par **Wistaro** Jeu 11 Sep 2014 - 6:54

J'ai utilisé le SourceCoder v3 de Cemetech, vu que TI-Editor ne fonctionne a priori plus (avec exportation html).

Je viens de me rendre compte que la page pour télécharger/partager de nouveaux niveaux niveaux n'est pas disponible, je corrige sa.

Pour le Label 2, peux-être qu'il s'agit d'une erreur de ma part^^

L'url http://sokobati.tk n'est finalement pas disponible, je mettrais donc à la place le lien raccourci

par Contenu sponsorisé

[prgm] SOKOBATI

[prgm] SOKOBATI

Re: [prgm] SOKOBATI

Re: [prgm] SOKOBATI

Re: [prgm] SOKOBATI


TI-Planet	Espace-TI : Forum